***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec. 19, 2024                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5544V-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.847
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=445.2  VTO=3.85  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=1.2296e12  gamma=1.01)
Rd     d1    d2    2.504e-3    TC=4.21e-3,8.15e-6
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=44  TBV1=5.855e-4 TBV2=5.05e-9  CJO=2.255e-9  M=1.027  VJ=7.118)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=1.695e-12  N=0.989  RS=4e-8  EG=1.18  TT=20n IKF=41.471 tikf=7.5e-4)
Rdiode  d1  21    1.638e-3 TC=4.5e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   5.58e-10
.MODEL     DGD    D(cjo=5.491e-10   M=1.252   VJ=5.298)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    2.2e-9
.ENDS PJQ5544V-AU
*$
